ワクチン接種後の発熱を見るのにIOT体温計を作った

#include <TFT_eSPI.h>
#include "Ambient.h"
#include <Wire.h>

#define LM75B_address 0x48
#define temp_reg 0x00

#define REPORTING_PERIOD_MS 600*1000 //データ送信間隔(ms)

WiFiClient client;
const char* ssid = "xxxxxxxxxxx"; //Wi-Fi APのSSID
const char* password = "xxxxxxxxxxx"; //Wi-Fi APのパスワード

Ambient ambient;
unsigned int channelId = xxxxxxxxxxx; // AmbientのチャネルID
const char* writeKey = "xxxxxxxxxxx"; // ライトキー

float sum_temp=0.0;
int cnt=0;
uint32_t tsLastReport=0;

TFT_eSPI tft = TFT_eSPI(); 

void setup() {
  //画面初期化
  tft.begin();
  tft.setRotation(1);
  tft.setTextSize(4);

  //Wi-Fi初期化
  WiFi.begin(ssid, password);  //Wi-Fi APに接続
  while (WiFi.status() != WL_CONNECTED) {  //Wi-Fi AP接続待ち
    delay(100);
  }
  ambient.begin(channelId, writeKey, &client); //Ambientを初期化

  //I2C接続
  Wire.begin();
  
  Wire.beginTransmission(LM75B_address);
  Wire.write(temp_reg);
  Wire.endTransmission();
  
  //デバッグ用
  //Serial.begin(115200);
}

float read_temp1(){
  signed int temp_data = 0;                   //LM75Bの温度レジスタの値用変数
  float temp = 0.0;                           //温度用変数

  Wire.requestFrom(LM75B_address,2);           
  while(Wire.available()){
    temp_data |= (Wire.read() << 8);         //温度レジスタの上位8bit取得
    temp_data |= Wire.read();                //温度レジスタの下位8bit取得(有効3bit)
  }
 
  temp = (temp_data >> 5) * 0.125;             //レジスタの値を温度情報に変換
 
  //Serial.println(temp);

  return temp;
}

void loop() {
  float temp;

  temp = read_temp1();
  
  tft.fillScreen(TFT_BLACK);
  tft.setCursor(0, 0);
  tft.setTextColor(TFT_WHITE);
  tft.print("Temp:");
  tft.println();
  tft.print(temp);
  tft.print(" deg");

  cnt++;
  sum_temp += temp;

  //データ送信処理
  if (millis() - tsLastReport > REPORTING_PERIOD_MS) {
    tsLastReport += REPORTING_PERIOD_MS;

    ambient.set(1, sum_temp/(float)cnt);
    ambient.send();

    cnt = 0;
    sum_temp = 0.0;
  }
  
  delay(1000);
}